@echo off
setlocal EnableExtensions
title INPRAISE - Vzdalena pomoc
set "CORE_URL=https://www.inpraise.cz/soubory/rustdesk/client/INPRAISE-Vzdalena-Pomoc.ps1"
set "CORE_FILE=%TEMP%\INPRAISE-Support-%RANDOM%-%RANDOM%.ps1"
set "EXPECTED_SHA256=e3ab86fadb809571dab378f6526d630468bed748971caad6bc9f53cca2aa87cc"
cls
echo.
echo ============================================================
echo               INPRAISE - VZDALENA POMOC
echo ============================================================
echo.
echo Pripravuji vzdalenou pomoc...
echo.
powershell.exe -NoProfile -ExecutionPolicy Bypass -Command "[Net.ServicePointManager]::SecurityProtocol=[Net.SecurityProtocolType]::Tls12; (New-Object System.Net.WebClient).DownloadFile($env:CORE_URL,$env:CORE_FILE)"
if errorlevel 1 goto download_error
if not exist "%CORE_FILE%" goto download_error
set "GOT_SHA256="
for /f "delims=" %%H in ('powershell.exe -NoProfile -ExecutionPolicy Bypass -Command "$sha=New-Object System.Security.Cryptography.SHA256Managed; $fs=[System.IO.File]::OpenRead($env:CORE_FILE); try { ([System.BitConverter]::ToString($sha.ComputeHash($fs))).Replace('-','').ToLower() } finally { $fs.Dispose(); $sha.Dispose() }"') do set "GOT_SHA256=%%H"
if /I not "%GOT_SHA256%"=="%EXPECTED_SHA256%" goto hash_error
powershell.exe -NoProfile -ExecutionPolicy Bypass -File "%CORE_FILE%"
exit /b %ERRORLEVEL%
:download_error
echo.
echo CHYBA: Nepodarilo se stahnout vzdalenou pomoc.
echo Zkontrolujte pripojeni k internetu a zkuste to znovu.
echo.
pause
exit /b 10
:hash_error
echo.
echo CHYBA: Kontrola stazeneho souboru selhala.
echo.
echo Ocekavano: %EXPECTED_SHA256%
echo Zjisteno:   %GOT_SHA256%
echo.
pause
exit /b 12